surma
1f49d0f7bb
Imported from the spike branch, with: - a library crate (Host API) for the CLI and the tests - JSON test scenarios for candidates - commit on close only for new or truncated files - a Nix flake: nix run -- init, nix run -- run
59 lines
1.9 KiB
Nix
59 lines
1.9 KiB
Nix
{
|
|
description = "Sausage: grow a system of WASI actors by talking to it";
|
|
|
|
inputs = {
|
|
nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
|
|
rust-overlay.url = "github:oxalica/rust-overlay";
|
|
rust-overlay.inputs.nixpkgs.follows = "nixpkgs";
|
|
};
|
|
|
|
outputs = { nixpkgs, rust-overlay, ... }:
|
|
let
|
|
systems = [ "x86_64-linux" "aarch64-linux" "x86_64-darwin" "aarch64-darwin" ];
|
|
forAll = f: nixpkgs.lib.genAttrs systems (system: f (import nixpkgs {
|
|
inherit system;
|
|
overlays = [ rust-overlay.overlays.default ];
|
|
}));
|
|
# The toolchain that builds the host and, at runtime, the actors.
|
|
rustFor = pkgs: pkgs.rust-bin.stable.latest.default.override {
|
|
targets = [ "wasm32-wasip2" ];
|
|
extensions = [ "rust-src" ];
|
|
};
|
|
sausageFor = pkgs:
|
|
let
|
|
rust = rustFor pkgs;
|
|
rustPlatform = pkgs.makeRustPlatform { cargo = rust; rustc = rust; };
|
|
in
|
|
rustPlatform.buildRustPackage {
|
|
pname = "sausage";
|
|
version = "0.1.0";
|
|
src = ./.;
|
|
cargoLock.lockFile = ./Cargo.lock;
|
|
cargoBuildFlags = [ "-p" "sausage" ];
|
|
doCheck = false;
|
|
nativeBuildInputs = [ pkgs.makeWrapper ];
|
|
# The `cargo` actor runs cargo at runtime. Build scripts need a C linker.
|
|
postInstall = ''
|
|
wrapProgram $out/bin/sausage --prefix PATH : ${pkgs.lib.makeBinPath [ rust pkgs.stdenv.cc ]}
|
|
'';
|
|
meta.mainProgram = "sausage";
|
|
};
|
|
in
|
|
{
|
|
packages = forAll (pkgs: { default = sausageFor pkgs; });
|
|
|
|
apps = forAll (pkgs: {
|
|
default = { type = "app"; program = "${sausageFor pkgs}/bin/sausage"; };
|
|
});
|
|
|
|
devShells = forAll (pkgs: {
|
|
default = pkgs.mkShell {
|
|
packages = [ (rustFor pkgs) pkgs.wasmtime pkgs.wasm-tools ];
|
|
shellHook = ''
|
|
export CARGO_HOME="$PWD/.cargo-home"
|
|
'';
|
|
};
|
|
});
|
|
};
|
|
}
|